Ein Comic-Verzeichnis

#!/usr/bin/perl

# Ein sehr einfaches Programm zur Bearbeitung von ComicsML-Dokumenten.
# Die Dokumente werden gelesen, die enthaltenen Strips in eine Liste eingefügt,
# und dann wird eine Webseite mit Links zu den betreffenden Comics ausgegeben.

use warnings;
use strict;

use XML::ComicsML; # ... damit wir ComicsML-Objekte bearbeiten können
use CGI qw(:standard);
use LWP;
use Date::Manip; # Ausgabe eines Datums ist sonst zu kompliziert

# Wir gehen davon aus, daß die URLs der ComicsML-Dokumente in einer
# Datei auf unserer Festplatte liegen, je eine URL pro Zeile.
# (Kein XML? Peinlich, peinlich ...)

my $url_file = $ARGV[0] or die "Usage: $0 url-file\n";

my @urls; # Liste der URLs
open (URLS, $url_file) or die "Kann die Datei $url_file nicht lesen: $!\n";
while (<URLS>) { chomp; push @urls, $_; }
close (URLS) or die "Kann die Datei $url_file nicht schließen: $!\n";

# Der LWP-UserAgent ist eine Art in Perl geschriebener Browser
my $ua = LWP::UserAgent->new;
my $parser = XML::ComicsML->new;

my @strips;            # Liste der gelesenen Comic-Strips

foreach my $url (@urls) {    
        my $request = HTTP::Request->new(GET=>$url);
        my $result = $ua->request($request);
        my $comic; # Das zu lesende Comic-Objekt
        if ($result->is_success) {
            # Versuchen wir, die Datei mit dem ComicsML-Parser zu lesen.
        unless ($comic = $parser->parse_string($result->content)) {
            # Sieht nicht gut aus...
            warn "Das Dokument $url ist kein korrektes XML-Dokument!\n";
            next;
            }
        } else {
           warn "Die URL $url konnte nicht gelesen werden: " . $result->status_line . "\n";
           next;
        }
        # Als nächstes extrahieren wir alle einzelnen Strips aus dem Comic. Jeder Strip
        # wird in eine Hashreferenz umgewandelt und abgelegt.
        foreach my $strip ($comic->strips) {
           push (@strips, {strip=>$strip, comic_title=>$comic->title, comic_url=>$comic->url});
        }
    }

    # Strips nach Datum sortieren und ausgeben (dazu verwenden wir die Funktion UnixDate
    # von Date::Manip).
    my @sorted = sort {UnixDate($$b{strip}->date, "%s") <=> UnixDate($$a{strip}->date, "%s")}
    @strips;

    # Als nächstes bauen wir eine Webseite.
    
    print header;
    print start_html("Die aktuellsten Comics");
    print h1("Links zu den aktuellsten Comics...");
    
    # Die sortierte Liste in umgekehrter Reihenfolge: aktuelle Comics zuerst
    foreach my $strip_info (@sorted) {
        my ($title, $url, $svg);
        my $strip = $$strip_info{strip};
           $title = join (" - ", $strip->title, $strip->date);
        # Link ausgeben
        if ($url = $strip->url) {
        $title = "<a href='$url'>$title</a>";
        }
        
        # Analog für den Titel des Comics
        my $comic_title = $$strip_info{comic_title};
        if ($$strip_info{comic_url}) {
           $comic_title = "<a href='$$strip_info{comic_url}'>$comic_title</a>";
        }
    
        # Titelzeile ausgeben
        print p("<b>$comic_title</b>: $title");
        
        print "<hr />";
    }

    print end_html;