Anpassen der Titelseiten für Romane
(Auszug aus "DocBook-XML: Medienneutrales und plattformunabhängiges Publizieren" von Thomas Schraitle)
Romane, die book verwenden und über chapter gegliedert werden, brauchen vier Anpassungen für die Titelseiten: drei für den Buchtitel (Schmutztitel, Haupttitel, Impressum) und eine für die jeweiligen Kapitel.
Beispiel: Titelseiten eines Romans
<xsl:template name="book.titlepage.before.recto">
<xsl:message>Schmutztitel</xsl:message>
<fo:block text-align="right" break-after="odd-page">
<xsl:apply-templates select="d:info/d:author" mode="book.titlepage.before.recto"/>
<xsl:text> - </xsl:text>
<xsl:apply-templates select="(d:info/d:title | d:title)[1]" mode="book.titlepage.before.recto"/>
</fo:block>
</xsl:template>
<xsl:template name="book.titlepage.recto">
<xsl:message>Haupttitel</xsl:message>
<fo:block text-align="center">
<fo:block font-size="12pt">
<xsl:apply-templates mode="book.titlepage.before.recto" select="d:info/d:author[1]"/>
</fo:block>
<fo:block>
<xsl:apply-templates mode="book.titlepage.recto.auto.mode" select="(d:info/d:title|d:title)[1]"/>
</fo:block>
<fo:block font-size="12pt" space-before=".5em">Roman</fo:block>
<fo:block-container top="16.5cm" bottom="2cm" absolute-position="absolute">
<fo:block >
<xsl:apply-templates mode="book.titlepage.recto.auto.mode" select="(d:info/d:publisher/d:publishername | d:info/d:publishername)[1]"/>
</fo:block>
</fo:block-container>
</fo:block>
</xsl:template>
<xsl:template name="book.titlepage.verso">
<xsl:message>Impressum</xsl:message>
<!-- ... -->
</xsl:template>Zeile 1: Erzeugt den "Schmutztitel", der vor dem Titel erscheint. Innerhalb des Templates werden Autor und Titel rechtsbündig ausgegeben. Durch break-after mit dem Wert odd-page wird eine Leerseite eingefügt, sodass der nachfolgende Titel auf einer ungeraden Seite beginnt.
Zeile 9: Erzeugt den Haupttitel. Im Haupttitel erscheinen Autor, Titel und Verlag. Letzteres wird mittels fo:block-container an einer absoluten Position eingefügt, um unabhängig von Titellänge und Zeilenumbrüchen zu sein.
Zeile 26: Erzeugt das Impressum. Dieses enthält in kleinerer Schriftart Autor, Titel und rechtliche Hinweise.
Transformieren Sie Ihr Dokument mit Hilfe obiger Einstellungen, ist das Ergebnis unbefriedigend: die Titel von Buch und Kapitel sind zu groß. Verwenden Sie die folgenden Modi, um die Titel entsprechend anzupassen:
Beispiel: Anpassen von Titeln in einem Roman
<xsl:template match="d:title" mode="book.titlepage.recto.auto.mode">
<fo:block font-size="{$body.font.master * 1.73}pt" space-before="1em">
<xsl:call-template name="division.title">
<xsl:with-param name="node" select="ancestor-or-self::d:book[1]"/>
</xsl:call-template>
</fo:block>
</xsl:template>
<xsl:template match="d:title" mode="book.titlepage.verso.auto.mode">
<fo:block font-size="{$body.font.master * 1.44}pt">
<xsl:call-template name="book.verso.title"/>
</fo:block>
</xsl:template>
<xsl:template match="d:title" mode="chapter.titlepage.recto.auto.mode">
<fo:block xsl:use-attribute-sets="chapter.titlepage.recto.style" font-size="{$body.font.master * 1.2}pt" font-family="{$body.font.family}" font-weight="normal" text-align="center" space-after="10em">
<xsl:apply-templates/>
</fo:block>
</xsl:template>Zeile 1: Formatiert den Buchtitel für die Haupttitelseite.
Zeile 8: Formatiert den Buchtitel für das Impressum.
Zeile 13: Formatiert einen Titel eines Kapitels für eine rechte Titelseite.
| << zurück | vor >> |
Copyright © 2009 Millin Verlag
Für Ihren privaten Gebrauch dürfen Sie die Online-Version ausdrucken.
Ansonsten unterliegt dieses Kapitel aus dem Buch "DocBook-XML: Medienneutrales und plattformunabhängiges Publizieren" denselben Bestimmungen, wie die gebundene Ausgabe: Das Werk einschließlich aller seiner Teile ist urheberrechtlich geschützt. Alle Rechte vorbehalten einschließlich der Vervielfältigung, Übersetzung, Mikroverfilmung sowie Einspeicherung und Verarbeitung in elektronischen Systemen.
Millin Verlag, Siebengebirgsring 36, 53797 Lohmar, info(at)millin.de